Hier ein kleines Beispiel für alle die mit chronologischer Reihung von Inhalten arbeiten. Es basiert auf dem Beitrag Twitter in Processing und stellt die letzten 200 Nachrichten eines Nutzers innerhalb der vorliegenden Zeitspanne dar.

Datumsangaben & Processing
Innerhalb von Processing nutzt man für Datumsangaben die Date-Klasse. Dabei dreht es sich (schrägerweise) um die verstrichenen Millisekunden seit dem 01.01.1970 (auch UNIX Time genannt). Durch diese abstrakte Repräsentation können Zeitpunkte einfach durch Operatoren verglichen bzw. Differenzen ermittelt werden. Der aktuelle Wert ist demnach ziemlich groß und passt nicht mehr in den Wertebereich eines Integers (int). Als nächst höhrerer Datentyp werden die Millisekunden deshalb in einer Variable vom Typ long gespeichert.

Axiale Verteilung
Um einen Datensatz chronologisch auf einer Achse zu verteilenen, benötigen wir drei Informationen:

1. Startzeitpunkt, ältester Eintrag
2. Endzeitpunkt, jüngster Eintrag
3. die aus beiden Zeitpunkten resultierende Zeitspanne

Im setup() durchläuft eine for-Schleife alle Twitter-Nachrichten und ermittelt den Beginn und das Ende des Zeitraumes. Dieser wird direkt nach der Schleife festgelegt und in Zeile 45 berechnet. Am Ende des setup()-Blocks werden zum Überprüfen beide Grenzen als Datum formatiert in der Konsole ausgegeben.

Startzeitpunkt und Zeitspanne dienen als Grundlage zur Verortung der einzelnen Nachrichten auf der x-Achse im Sketch. Das Verhältnis einer jeden Nachricht (Zeitraum zwischen der Veröffentlichung zum Startzeitpunk) zur gesamten Zeitspanne ergibt einen Wert zwischen 0 und 1. Dabei ist 0 der Startzeitpunkt und 1 der Moment an dem der letzte Beitrag erschien. Dieser Wert mulipliziert mit der Länge der Zeitachse ergibt die Position auf ihr. Im unteren Beispiel wird die gesamte x-Achse als Zeitleiste angesehen. Folglich wird der Faktor auf die Breite des Fensters angewendet. Im letzten Schritt wird die Textlänge der Beiträge für die Lage der Linien genutzt.

Fazit
Knackpunkt bei der Verteilung ist die Berechnung in Zeile 68, durch das Mappen der relativen Position des Zeitpunktes in der Zeitspanne auf die Repräsentation mit der Länge der Zeitachse. Da die Twitter-Nachrichten chronologisch sortiert geladen werden, hätte man die erste Schleife im setup() enfallen lassen können. Zur Vollstänigkeit haben wir trotzdem die umständliche Version gewählt.

import twitter4j.org.json.*;
import twitter4j.*;
import twitter4j.http.*;
import twitter4j.examples.*;
import java.util.List;
import java.util.Date;

List stats;    // Liste der Twitter-Einträge
long timeMax;  // time-stamp aktuellster Eintrag
long timeMin;  // time-stamp ältester Eintrag
long timeDur;  // Zeit zwischen ältestem und aktuellstem

void setup () {
  size (580, 150);
  Twitter tw = new Twitter ("Benutzername", "Passwort");

  // Startwerte der von min und max definieren.
  // Diese Werte sind unrealistisch für beide Größen.
  timeMax = 0;
  timeMin = -1;

  try {
    // Die letzten 200 Twitter-Einträge des Benutzers.
    // (muss nicht der bei 'new Twitter(' angegebene sein)
    stats = tw.getUserTimeline ("Benutzername", 200);

    // Für jeden Twitter-Eintrag ('Status')
    for (int i=0; i < stats.size(); i++) {
      Status stat = (Status) stats.get (i);

      // Zeitpunkt der Veröffentlichung
      long time = stat.getCreatedAt ().getTime ();

      // Ist der Eintrag der erste?
      if (time < timeMin || timeMin == -1) {
        timeMin = time;
      }
      // oder der letzte?
      if (time > timeMax) {
        timeMax = time;
      }
    }
    // Zeitspanne zwischen dem ersten
    // und dem letzten Eintrag in der Liste
    timeDur = timeMax - timeMin;
  }catch (Exception e) {
    println (e);
  }
  println ("start: " + new Date (timeMin));
  println ("end:   " + new Date (timeMax));
}

void draw () {
  background (40);
  stroke (255, 150);

  Status stat;  // Var. zum Ablegen eines Eintrages
  double time;  // Var. für die Zeitspannenberechnung

  // Für jeden Twitter-Eintrag ('Status')
  for (int i=0; i < stats.size (); i++) {
    stat = (Status) stats.get (i);

    // Zeitspanne im Vergleich zum ältesten Eintrag
    time = stat.getCreatedAt ().getTime () - timeMin;

    // Lage auf der x-Achse
    float x = width * (float) (time / timeDur);
    // y-Position der Linienenden, bestimmt durch Textlänge
    float y1 = height / 2 - stat.getText ().length () / 2;
    float y2 = height / 2 + stat.getText ().length () / 2;

    line (x, y1, x, y2);
  }
}